u:=0.4cm;
r:=2pt;

filenametemplate "homework-6-sol-streets.mps";
beginfig(1);
n:=6;
for i=0 upto n-1:
	draw (0,i*u)--((n-1)*u,i*u);
	draw (i*u,0)--(i*u,(n-1)*u);
endfor
pickup pencircle scaled 2r;
draw (0,0);  draw ((n-1)*u,(n-1)*u);
label.lft(btex$A$etex, (0,0)+r*dir180);
label.rt(btex$B$etex, ((n-1)*u,(n-1)*u)+r*dir0);
endfig;

u:=1cm;

filenametemplate "homework-6-sol-chords.mps";
beginfig(1);
n:=7;
theta1:=30;
theta2:=95;
theta3:=135;
theta4:=-175;
theta5:=-140;
theta6:=-80;
theta7:=-10;
for i=1 upto n:  x[i]=u*cosd(theta[i]);  y[i]=u*sind(theta[i]);  endfor
draw (u,0)  for t=20 step 20 until 340:  ..(u*cosd(t),u*sind(t))  endfor  ..cycle;
draw z1--z4;  draw z2--z6;
pickup pencircle scaled 2r;
for i=1 upto n:  draw z[i];  endfor
endfig;

u:=2.54cm;
g:=10pt;

filenametemplate "homework-6-sol-square.mps";
beginfig(1);
draw (0,0)--(2u,0)--(2u,2u)--(0,2u)--cycle;
draw (u,0)--(u,2u) dashed evenly;
draw (0,u)--(2u,u) dashed evenly;
z0=(0,0)+g*dir180;
z1=(0,2u)+g*dir180;
z2=(0,2u)+g*dir90;
z3=(2u,2u)+g*dir90;
z4=(u,u)+g*dir0;
z5=(u,2u)+g*dir0;
z6=(0,u)+g*dir-90;
z7=(u,u)+g*dir-90;
drawdblarrow z0--z1;
drawdblarrow z2--z3;
drawdblarrow z4--z5;
drawdblarrow z6--z7;
drawdblarrow (0,2u)--(u,u);
picture lab;
lab:=thelabel(btex$\rm2\,m$etex, 0.5[z0,z1]);              unfill bbox lab;  draw lab;
lab:=thelabel(btex$\rm2\,m$etex, 0.5[z2,z3]);              unfill bbox lab;  draw lab;
lab:=thelabel(btex$\rm1\,m$etex, 0.5[z4,z5]);              unfill bbox lab;  draw lab;
lab:=thelabel(btex$\rm1\,m$etex, 0.5[z6,z7]);              unfill bbox lab;  draw lab;
lab:=thelabel(btex$\rm\sqrt2\,m$etex, 0.5[(0,2u),(u,u)]);  unfill bbox lab;  draw lab;
endfig;

end;