u:=2cm;
r:=3.5pt;

filenametemplate "homework-1-sol-cube.mps";
beginfig(1);
z0=(0,0);
z1=z0+u*dir-145;
z2=z0+u*dir-35;
z4=z0+0.9u*dir-90;
z4-z5=z0-z1;
z1-z3=z4-z6=z5-z7=z0-z2;
draw z1--z0--z2--z3--z1--z5--z7--z6--z2;
draw z3--z7;
draw z0--z4--z5 dashed evenly;
draw z4--z6 dashed evenly;
z8=z0+0.5u*dir90;
pickup pencircle scaled 0.3;
draw z0--z8;
draw z8--3z8/2-z0 dashed evenly scaled 0.5;
pickup pencircle scaled 2r;
for i=0 step 1 until 7:  draw z[i];  endfor
pickup pencircle scaled (2r-1);
for i=1, 2, 4, 7:  draw z[i] withcolor white;  endfor
endfig;

t:=1cm;
def linethru(expr a, b)=draw a+t*dir angle(a-b)--b+t*dir angle(b-a); enddef;

filenametemplate "homework-1-sol-star.mps";
beginfig(2);
for i=0 upto 4:  z[i]=u*dir(90-72i);  endfor
for i=0 upto 4:
	z[i+5]=whatever[z[i],z[(i+2)mod5]]=whatever[z[(i+1)mod5],z[(i+3)mod5]];
endfor
for i=0 upto 4:  linethru(z[i],z[(i+2)mod5]); endfor
pickup pencircle scaled 2r;
for i=0 upto 9:  draw z[i];  endfor
endfig;

filenametemplate "homework-1-sol-tepee.mps";
beginfig(3);
z0=(0,0);
z1=z0+2u*dir-105;
x2-x0=x0-x1;
x1-x4=x5-x2=0.5u;
y1=y2=y4=y5;
z3=z0+1.2u*dir-90;
z6=whatever[z0,z1]=whatever[z3,z5];
z7=whatever[z0,z2]=whatever[z3,z4];
z8=whatever[z0,z1]=whatever[z3,z4];
z9=whatever[z0,z2]=whatever[z3,z5];
linethru(z0,z1);
linethru(z0,z2);
linethru(z4,z5);
linethru(z4,z7);
linethru(z5,z6);
pickup pencircle scaled 2r;
for i=0 upto 9:  draw z[i];  endfor
endfig;

u:=0.006cm;
filenametemplate "homework-1-sol-tetrahedron.mps";
beginfig(4);
z0=(37u,209u);
z1=(676u,192u);
z2=(353u,655u);
z3=(308u,68u);
draw z0--z3--z2--z0;
draw z3--z1--z2;
draw z0--z1 dashed evenly;
pickup pencircle scaled 2r;
for i=0 upto 3:  draw z[i];  endfor
endfig;

end;